	@setlocal
	@echo off

	set thisfolder=%~dp0

	set nametouse=
	set /P nametouse="Укажите имя учетной записи администратора (по умолчанию - Администратор): "
	if [%nametouse%] == [] (
		set nametouse=Администратор
	)
	echo Будет использована учетная запись %nametouse%

:runasadm

	echo.
	echo Укажите каталог для установки (например D:\Stimgw).
	set /P folder="Если пемещать ненужно, нажмите ENTER: "
	if [%folder%] == [] (
		set folder=%thisfolder%
		goto :nocopy
	)

	if exist %folder% goto :nomkdir

	mkdir %folder% > NUL
	if not errorlevel 0 goto :failure

:nomkdir

	copy /y %thisfolder%*.* %folder% > NUL
	if not errorlevel 0 goto :failure

:nocopy

	echo.
	echo Список доступных интернет адресов:
	ipconfig | findstr "\<IPv4"

	echo.
	echo Настройка сервиса Stimgw ...

:config

	echo.
	set /P localip="Укажите локальный IPv4 адрес: "
	set localport=
	set /P localport="Укажите локальный порт (по умолчанию 8080): "
	if [%localport%] == [] (
		set localport=8080
	)

	set remoteip=
	set /P remoteip="Укажите IPv4 адрес сервера АС СМЕТА (по умолчанию buch.mosreg.ru): "
	if [%remoteip%] == [] (
		set remoteip=buch.mosreg.ru
	)

	set remoteport=
	set /P remoteport="Укажите порт сервера АС СМЕТА (по умолчанию 8080): "
	if [%remoteport%] == [] (
		set remoteport=8080
	)

	echo.
	echo Проверьте текущие настройки
	echo Локальный IPv4 адрес ................. %localip%
	echo Локальный порт ....................... %localport%
	echo IPv4 адрес сервера АС СМЕТА .......... %remoteip%
	echo Порт сервера АС СМЕТА ................ %remoteport%
	echo.

:configyesno

	set yesno=
	set /P yesno="Являются ли настройки правильными (y\n): "
	if [%yesno%] == [n] (
		goto :config
	)

	if not [%yesno%] == [y] (
		goto :configyesno
	)

	echo [local] > %folder%\Stimgw.ini
	echo ip=%localip% >> %folder%\Stimgw.ini
	echo port=%localport% >> %folder%\Stimgw.ini
	echo [remote] >> %folder%\Stimgw.ini
	echo ip=%remoteip% >> %folder%\Stimgw.ini
	echo port=%remoteport% >> %folder%\Stimgw.ini
	echo NoStimWebSrvCheck=1 >> %folder%\Stimgw.ini
	echo [log] >> %folder%\Stimgw.ini
	echo debug=1 >> %folder%\Stimgw.ini
	echo debuglink=0 >> %folder%\Stimgw.ini
	echo debugfix=0 >> %folder%\Stimgw.ini

	echo.
	echo Регистрация сервиса Stimgw ...
	runas /user:%nametouse% "%folder%\Stimgw.exe /INSTALL"
	if not errorlevel 0 goto :failure

	echo.
	echo Запуск сервиса Stimgw ...
	runas /user:%nametouse% "sc start Stimgw"
	if not errorlevel 0 goto :failure

	echo Завершено успешно

	echo.
	echo При запуске клиента АС СМЕТА необходимо указать адрес сервера: %localip%:%localport%
	echo ВНИМАНИЕ: поскольку данное соединение локальное - использование прокси необходимо
	echo запретить (отключить Параметры подключения\Сервер\Настройки\Использовать прокси-сервер)
	echo.

	goto :exit

:failure

	echo Установка прервана
	goto :exit

:exit

	pause
